top page > computer > web > rfc > rfc7159
更新日:
文責: 重城良国

RFC 7159 JSON

(工事中 0%)

翻訳

ABNF

JSON-text = ws value ws

begin-array = ws %x5B ws; [ 左角括弧

begin-object = ws %x7B ws; { 左波括弧

end-array = ws %x5D ws; ] 右角括弧

end-object = ws %x7D ws; } 右波括弧

name-separator = ws %x3A ws; : colon

value-separator = ws %x2C ws; , comma

ws = *(
%x20 / ; スペース
%x09 / ; 水平タブ
%x0A / ; 行送りまたは改行
%x0D ) ; 復帰

value = false / null / true / object / array / number / string

false = %x66.61.6c.73.65 ; false

null = %x6e.75.6c.6c ; null

true = %x74.72.75.65 ; true

object = begin-object [ member *( value-separator member ) ] end-object

member = string name-separator value

array = begin-array [ value *( value-separator value ) ] end-array

number = [ minus ] int [ frac ] [ exp ]

decimal-point = %x2E ; .

digit1-9 = %x31-39 ; 1-9

e = %x65 / %x45 ; e E

exp = e [ minus / plus ] 1*DIGIT

frac = decimal-point 1*DIGIT

int = zero / ( digit1-9 *DIGIT )

minus = %x2D ; -

plus = %x2B ; +

zero = %x30 ; 0

string = quotation-mark *char quotation-mark

char = unescaped /
%x22 / ; " 引用符 U+0022
%x5C / ; \ 逆斜線 U+005C
%x2F / ; / 斜線 U+002F
%x62 / ; b バックスペース U+0008
%x66 / ; f 改ページ U+000C
%x6E / ; n 行送り U+000A
%x72 / ; r 復帰 U+000D
%x74 / ; t タブ U+0009
%x75 4HEXDIG ) ; uXXXX U+ XXXX

escape = %x5C ; \

quotation-mark = %x22 ; "

unescaped = %x20-21 / %x23-5B / %x5d-10FFFF

ノート

UTF-8が望ましいがUTF-16やUTF-32も使える。

正当なCSSです! HTML5 Powered with CSS3 / styling, and Semantics